[@假人换装J]
{
#IF
CheckLevelEx > 0
#ACT
MOV S$捡到的装备 <$CURRTEMNAME>

#IF
CHECKJOB warrior
#ACT
mov N$战斗力 <$MAXDC>

#IF
CHECKJOB wizard
#ACT
mov N$战斗力 <$MAXMC>
#IF
CHECKJOB taoist
#ACT
mov N$战斗力 <$MAXSC>


#IF
CheckLevelEx > 0
#ACT
MOV N$前战斗力 <$STR(N$战斗力)>
;SENDMSG 0 <$USERNAME>----前战斗力:<$STR(N$前战斗力)>

MOV N$假人_操作位置 99999
;-------------------------------------------
#OR
EQUAL <$CURRTEMSTDMODE> 10
EQUAL <$CURRTEMSTDMODE> 11
#ACT
MOV N$假人_操作位置 0
MOV S$换掉的装备 <$DRESS>

#OR
EQUAL <$CURRTEMSTDMODE> 5
EQUAL <$CURRTEMSTDMODE> 6
#ACT
MOV N$假人_操作位置 1
MOV S$换掉的装备 <$WEAPON>

#OR
EQUAL <$CURRTEMSTDMODE> 29
EQUAL <$CURRTEMSTDMODE> 30
#ACT
MOV N$假人_操作位置 2
MOV S$换掉的装备 <$RIGHTHAND>

#OR
EQUAL <$CURRTEMSTDMODE> 19
EQUAL <$CURRTEMSTDMODE> 20
EQUAL <$CURRTEMSTDMODE> 21
#ACT
MOV N$假人_操作位置 3
MOV S$换掉的装备 <$NECKLACE>

#OR
EQUAL <$CURRTEMSTDMODE> 24
EQUAL <$CURRTEMSTDMODE> 26
#ACT
MOVR N$假人_操作位置 5 7
MOV S$换掉的装备 <$ARMRING_R>

#OR
EQUAL <$CURRTEMSTDMODE> 22
EQUAL <$CURRTEMSTDMODE> 23
#ACT
MOVR N$假人_操作位置 7 9
MOV S$换掉的装备 <$RING_R>

#IF
EQUAL <$CURRTEMSTDMODE> 15
#ACT
MOV N$假人_操作位置 4
MOV S$换掉的装备 <$HELMET>
#IF
EQUAL <$CURRTEMSTDMODE> 16
#ACT
MOV N$假人_操作位置 13
MOV S$换掉的装备 <$HAT>

#IF
EQUAL <$CURRTEMSTDMODE> 25
#ACT
MOV N$假人_操作位置 9
MOV S$换掉的装备 <$BUJUK>

#IF
EQUAL <$CURRTEMSTDMODE> 28
#ACT
MOV N$假人_操作位置 15
MOV S$换掉的装备 <$HORSE>

#IF
EQUAL <$CURRTEMSTDMODE> 48
#ACT
MOV N$假人_操作位置 16
MOV S$换掉的装备 <$SHIELD>

#IF
EQUAL <$CURRTEMSTDMODE> 62
#ACT
MOV N$假人_操作位置 11
MOV S$换掉的装备 <$BOOTS>
#IF
EQUAL <$CURRTEMSTDMODE> 63
#ACT
MOV N$假人_操作位置 12
MOV S$换掉的装备 <$CHARM>
#IF
EQUAL <$CURRTEMSTDMODE> 64
#ACT
MOV N$假人_操作位置 10
MOV S$换掉的装备 <$BELT>

#IF
EQUAL <$CURRTEMSTDMODE> 65
#ACT
MOV N$假人_操作位置 14
MOV S$换掉的装备 <$DRUM>


#IF
EQUAL N$假人_操作位置 99999
#ACT
TAKE <$STR(S$捡到的装备)> 1
;SENDMSG 0 <$USERNAME>-----------------------------------------清理
BREAK
;-------------------------------------------

#IF
CheckLevelEx > 0
#ACT
;SENDMSG 0 <$USERNAME>捡到:<$CURRTEMNAME>/StdMode:<$CURRTEMSTDMODE>/<$STR(N$假人_操作位置)>
;SENDMSG 0 <$USERNAME>:换掉:<$STR(S$换掉的装备)>
AutoTakeOnItem <$STR(S$捡到的装备)> <$STR(N$假人_操作位置)>

#IF
CHECKJOB warrior
#ACT
mov N$战斗力 <$MAXDC>
#IF
CHECKJOB wizard
#ACT
mov N$战斗力 <$MAXMC>
#IF
CHECKJOB taoist
#ACT
mov N$战斗力 <$MAXSC>

#IF
CheckLevelEx > 0
#ACT
MOV N$后战斗力 <$STR(N$战斗力)>
;SENDMSG 0 <$USERNAME>----后战斗力:<$STR(N$后战斗力)>



#IF
NOT large N$后战斗力 <$STR(N$前战斗力)> 
#ACT
AutoTakeOffItem <$STR(N$假人_操作位置)>
AutoTakeOnItem <$STR(S$换掉的装备)> <$STR(N$假人_操作位置)>
;SENDMSG 0 <$USERNAME>:------------------------------返回
}